Verification of the Tomimatsu-Sato solutions for nTS = 1, 2, 3
		(Progr. Theor. Phys. 50, No 1, p 95, 1973)

\(
\)

<< EDCRGTCcode.m

{$VersionNumber, $RGTCversion}

Basic Definitions

nTS is used instead of δ. The scale factor m in the equation relating cylindrical and prolate spheroidal coordinates has been set equal to δ/p.

xCoord = {t, φ, x, y};

coFR
       = {d[t] - 
          2  nTS q/p (1 - y^2) Cf[x, y]/Af[x, y] d[φ], 
        d[φ], d[x], d[y]};

gTS = 
      DiagonalMatrix[{Af[x, y]/Bf[x, y], 
          -Bf[x, y]/Af[x, y] (x^2 - 1) (1 - y^2), 
          -Bf[x, y]/Kf[x, y]/(x^2 - 1), 
          -Bf[x, y]/Kf[x, y]/(1 - y^2)}];

Definitions of Af, Bf, Cf, Kf for nTS = 1, 2, 3

Kf[n_] := p^(2  n) (x^2 - y^2)^(n^2 - 1)

\(
\)

Af[1] = p^2  x^2 - 1 + q^2  y^2; \(
\)Bf[1] = (p x + 1)^2 + q^2  y^2; \(
\)Cf[1] = -(p x + 1);

\(
\)

$x2 = (x^2 - 1); $y2 = (1 - y^2);

Af[2] = 
      p^4  $x2^4 + q^4  $y2^4 - 
        2  p^2  q^2  $x2 $y2 (3  $x2 $y2 + 2  $x2^2 + 2  $y2^2);

Bf[2] = 
      (p^2 (x^4 - 1) + q^2 (y^4 - 1) + 2  p x $x2)^2 + 
        4  q^2  y^2 (p x $x2 + (p x + 1) $y2)^2;

Cf[2] = 
      -p^3 x $x2 (2 (x^4 - 1) + (x^2 + 3) $y2) - 
        p^2  $x2 (4  x^2  $x2 + (3  x^2 + 1) $y2) + 
        q^2 (p x + 1) $y2^3;

\(
\)

Af[3] = 
      p^6  $x2^9 - q^6  $y2^9 - 
        3  p^4  q^2  $x2^4  $y2 
          (3  $x2^4 + 12  $x2^3  $y2 + 28  $x2^2  $y2^2 + 30  $x2 $y2^3 + 
              12  $y2^4) + 
        3  p^2  q^4  $x2 $y2^4 
          (3  $y2^4 + 12  $y2^3  $x2 + 28  $x2^2  $y2^2 + 30  $y2 $x2^3 + 
              12  $x2^4);

Bf[3] = 
      (p (x^3 + 3  x) $x2^3 - 
              p q^2 (x^3 + 3  x y^2) ($x2 + $y2)^3 + 
              p^2 (3  x^2 + 1) $x2^3 - q^2 (3  y^2 + 1) $y2^3)^2 + 
        q^2  y^2 
          (p^2 (3  x^2 + y^2) ($x2 + $y2)^3 - (y^2 + 3) $y2^3 + 
                12  p x ($x2 + $y2) ($x2*$y2))^2;

Cf[3] = 
      -p^5 x $x2^4 
          ($x2^2 (3  x^2 + 1) (x^2 + 3) + 
              4  $x2 $y2 (x^4 + 8  x^2 + 3) + 
              2  $y2^2 (x^4 + 10  x^2 + 5)) + 
        p^3  q^2  x $x2 $y2^3 
          (8  $x2^2 (3  x^4 - 4  x^2 - 3) + 
              4  $x2 $y2 (13  x^4 - 10  x^2 - 15) + 
              4  $y2^2 (9  x^4 - 13) + 6  $y2^3 (x^2 + 3)) - 
        p^4  $x2^4 
          ($x2^2 (3  x^2 + 1)^2 + 
              2  $x2 $y2 (9  x^4 + 14  x^2 + 1) + 
              2  $y2^2 (5  x^4 + 10  x^2 + 1)) + 
        p^2  q^2  $x2 $y2^3 
          (54  $x2^3  $y2 + 4  $x2^2 (9  x^4 - 18  x^2 + 1) + 
              4  $x2 $y2 (9  x^4 - 8  x^2 - 13) + 
              6  $y2^3 (3  x^2 + 1) + 
              2  $y2^2 (37  x^4 - 42  x^2 - 3)) - 
        q^4 (p x + 1) $y2^8;

\(
\)

TSsol[n_] := {nTS -> n, H_[x, y] :> H[n]}

d[p] = 0; d[q] = 0;

p and q satisfy p^2+q^2=1. So use one of the following in simpRules:

pTOq
       = {p^n_ :> p^Mod[n, 2] (1 - q^2)^Floor[n/2] /; n > 1};

qTOp
       = {q^n_ :> q^Mod[n, 2] (1 - p^2)^Floor[n/2] /; n > 1};

simpRules = qTOp

If one uses pTOq instead, the calculation takes much longer!

\(
\)

Verification of TS solution n=1:

RGtensors[FacSimp[gTS //. TSsol[1]], xCoord, 
        FacSimp[coFR //. TSsol[1]], {0, 0}]

\(
\)

Clear$dx

Verification of TS solution n=2:

RGtensors[FacSimp[gTS //. TSsol[2]], xCoord, 
        FacSimp[coFR //. TSsol[2]], {0, 0}]

\(
\)

Clear$dx

Verification of TS solution n=3:

RGtensors[FacSimp[gTS //. TSsol[3]], xCoord, 
        FacSimp[coFR //. TSsol[3]], {0, 0}]

MaxMemoryUsed[]